self: super: {
  freeradius = super.freeradius.override {
    withJson = true;
    withRest = true;
  };

  python3 = let packageOverrides = final: prev: import ./python final prev;
  in super.python3.override { inherit packageOverrides; };
  python39 = let packageOverrides = final: prev: import ./python final prev;
  in super.python39.override { inherit packageOverrides; };

  yate = super.yate.overrideAttrs (old: {
    configureFlags =
      [ "--with-libpq=${self.postgresql.withPackages (ps: [ ])}" ];
  });

  t38modem = self.callPackage ./t38modem.nix { };
  ptlib = self.callPackage ./ptlib.nix { };
  opal = self.callPackage ./opal.nix { };
  eapol_test = super.wpa_supplicant.overrideAttrs (old: rec {
    name = "eapol_test-${old.version}";

    buildPhase = ''
      runHook preBuild
      echo CONFIG_EAPOL_TEST=y >> .config
      make eapol_test
      runHook postBuild
    '';

    installPhase = ''
      install -D eapol_test $out/bin/eapol_test
    '';

    NIX_CFLAGS_COMPILE = [ "-Wno-error" ];
  });
}