59 lines
1.9 KiB
Nix
59 lines
1.9 KiB
Nix
{ self, nixpkgs, fernglas, fieldpoc, nixos-exporter, solid-xmpp-alarm, sops-nix, ... }@inputs:
|
|
|
|
rec {
|
|
generateNixosSystem = {
|
|
name,
|
|
system ? "x86_64-linux",
|
|
group ? null,
|
|
modules ? [],
|
|
}: let
|
|
localNixpkgs = nixpkgs.lib.attrByPath [ "nixpkgs-${name}" ] nixpkgs inputs;
|
|
in localNixpkgs.lib.nixosSystem {
|
|
system = system;
|
|
modules = modules ++ [
|
|
self.nixosModules.clerie
|
|
({ ... }: {
|
|
/*
|
|
Make the contents of the flake availiable to modules.
|
|
Useful for having the monitoring server scraping the
|
|
target config from all other servers automatically.
|
|
*/
|
|
_module.args = {
|
|
inputs = inputs;
|
|
_nixfiles = self;
|
|
};
|
|
})
|
|
../configuration/common
|
|
../users/clerie
|
|
({ ... }: {
|
|
nixpkgs.overlays = [
|
|
self.overlays.nixfilesInputs
|
|
self.overlays.clerie
|
|
];
|
|
clerie.monitoring = nixpkgs.lib.attrsets.optionalAttrs (group != null) { serviceLevel = group; };
|
|
})
|
|
fernglas.nixosModules.default
|
|
fieldpoc.nixosModules.default
|
|
nixos-exporter.nixosModules.default
|
|
solid-xmpp-alarm.nixosModules.solid-xmpp-alarm
|
|
sops-nix.nixosModules.sops
|
|
(../hosts + "/${name}/configuration.nix")
|
|
# Automatically load secrets from sops file for host
|
|
({ config, lib, ... }: {
|
|
sops.defaultSopsFile = ../hosts + "/${name}/secrets.json";
|
|
sops.secrets = let
|
|
secretFile = config.sops.defaultSopsFile;
|
|
secretNames = builtins.filter (name: name != "sops") (builtins.attrNames (builtins.fromJSON (builtins.readFile secretFile)));
|
|
secrets = if builtins.pathExists secretFile then
|
|
lib.listToAttrs (builtins.map (name: lib.nameValuePair name {}) secretNames)
|
|
else
|
|
{};
|
|
in
|
|
secrets;
|
|
})
|
|
];
|
|
};
|
|
|
|
mapToNixosConfigurations = hosts: builtins.mapAttrs (name: host: generateNixosSystem host) hosts;
|
|
}
|