nixfiles/hosts/carbon/configuration.nix

{ config, pkgs, lib, ... }:

{
  imports =
    [
      ./hardware-configuration.nix
      ../../configuration/common
      ../../configuration/router
    ];

  boot.kernelParams = [ "console=ttyS0,115200n8" ];

  boot.loader.grub.enable = true;
  boot.loader.grub.version = 2;
  boot.loader.grub.device = "/dev/sda";
  boot.loader.grub.extraConfig = "
    serial --speed=115200 --unit=0 --word=8 --parity=no --stop=1
    terminal_input serial
    terminal_output serial
  ";

  networking.hostName = "carbon";

  networking.useDHCP = false;
  # Local Router IPs
  networking.interfaces.lo.ipv6.addresses = [
    { address = "fd00:152:152:104::1"; prefixLength = 64; }
    { address = "fd00:152:152::1"; prefixLength = 128; } # Anycast
  ];
  networking.interfaces.lo.ipv4.addresses = [
    { address = "10.152.104.1"; prefixLength = 24; }
    { address = "10.152.0.1"; prefixLength = 32; } # Anycast
  ];
  # Network
  networking.interfaces.enp1s0.useDHCP = true;
  networking.interfaces.enp2s0.ipv6.addresses = [ { address = "fd00:152:152:4::1"; prefixLength = 64; } ];
  networking.interfaces.enp2s0.ipv4.addresses = [ { address = "10.152.4.1"; prefixLength = 24; } ];

  networking.nat = {
    enableIPv6 = true;
    enable = true;
    externalInterface = "enp1s0";
    internalIPv6s = [ "fd00:152:152::/48" ];
    internalIPs = [ "10.152.0.0/16" ];
  };

  networking.wireguard.enable = true;
  networking.wireguard.interfaces = {
    wg-porter = {
      ips = [ "fe80::138:2/64" "169.254.138.2/24" ];
      peers = [ {
          allowedIPs = [ "0.0.0.0/0" "::/0" ];
          endpoint = "porter.net.clerie.de:50138";
          publicKey = "aP6optNE7nVk6coo+USkSDtB62rAc/isfofRML9V2HM=";
          persistentKeepalive = 25;
      } ];
      allowedIPsAsRoutes = false;
      privateKeyFile = "/var/src/secrets/wireguard/wg-porter";
    };
  };

  petabyte.policyrouting = {
    enable = true;
    rules6 = [
      { rule = "from all to fd00:152:152::/48 lookup 1000"; prio = 10000; } # OSPF
      { rule = "from fd00:152:152::/48 lookup 2000"; prio = 10000; } # BGP
      { rule = "from all to fd00:152:152::/48 unreachable"; prio = 20000; }
    ];
    rules4 = [
      { rule = "from all to 10.152.0.0/16 lookup 1000"; prio = 10000; } # OSPF
      { rule = "from 10.152.0.0/16 lookup 2000"; prio = 10000; } # BGP
      { rule = "from all to 10.152.0.0/16 unreachable"; prio = 20000; }
    ];
  };

  services.bird2.enable = true;
  services.bird2.config = ''
  router id ${ (lib.head config.networking.interfaces.lo.ipv4.addresses).address };

  ipv6 table ospf6;
  ipv4 table ospf4;

  protocol direct direct_lo {
    interface "lo";
    ipv6 {
      table ospf6;
    };
    ipv4 {
      table ospf4;
    };
  }

  protocol direct direct_enp2s0 {
    interface "enp2s0";
    ipv6 {
      table ospf6;
    };
    ipv4 {
      table ospf4;
    };
  }

  protocol kernel kernel_ospf6 {
    kernel table 1000;
    ipv6 {
      table ospf6;
      export filter {
        krt_prefsrc=${ (lib.head config.networking.interfaces.lo.ipv6.addresses).address };
        accept;
      };
      import none;
    };
  }

  protocol kernel kernel_ospf4 {
    kernel table 1000;
    ipv4 {
      table ospf4;
      export filter {
        krt_prefsrc=${ (lib.head config.networking.interfaces.lo.ipv4.addresses).address };
        accept;
      };
      import none;
    };
  }

  protocol ospf v3 ospf_6 {
    ipv6 {
      table ospf6;
      import all;
      export all;
    };
    area 0 {
      interface "wg-porter" {
        cost 80;
        type pointopoint;
      };
    };
  }

  protocol ospf v3 ospf_4 {
    ipv4 {
      table ospf4;
      import all;
      export all;
    };
    area 0 {
      interface "wg-porter" {
        cost 80;
        type pointopoint;
      };
    };
  }

  protocol device {
    scan time 10;
  }
  '';

  system.stateVersion = "21.03";
}